/**
 * Inspiration #2
 * d'apres la musique Nara, de Ex Posthumus
 *
 * http://oroooroo.blogspot.com/2009/02/inspiration-partie-2-billet.html
 * 
 * Par Xavier GOUCHET, 2009
 * http://www.xgouchet.fr/blog/
 *
 */

boolean debug = false;
float px, py;
int ix, iy;
float dx, dy;
int g = 50;
float s = 30;
float angle = 0;
color fogcolor = color(0,0,16);


void setup(){
  size(640, 480, P3D);
  px = 0;
  py = 0;
}

void draw() {
  background(fogcolor);

  if (debug){
    stroke(255);
    noFill();
  }
  else {
    noStroke();
  }

  // Mouse Nav
  float dmx = (mouseX - (width/2)) * 0.001;
  angle += dmx*0.05;

  // Speed 
  px += sin(angle) * 0.1;
  py -= cos(angle) * 0.1;

  ix = (int) Math.floor(px);
  iy = (int) Math.floor(py);
  dx = ix - px;
  dy = iy - py;

  pushMatrix();
  //lights();
  translate(width*0.5 , height*0.65, g*s);
  rotateZ(-dmx*0.5);
  //rotateX(-dmy);
  rotateX(-0.05);
  rotateY(angle);

  renderGrid();
  renderWater();
  popMatrix();

}

void renderGrid(){
  noiseDetail(1,0);

  for (int i=-g; i<g; i++){
    beginShape(QUAD_STRIP); 
    for (int j=-g; j<=g; j++){

      float rx1 = ix + i;
      float rx2 = ix + i + 1;
      float rz = iy + j;

      float y1 = 200 * noise(rx1*0.2,rz*0.1);
      y1 += 40 * noise(rx1*0.5,rz*0.5);
      y1 += 15 * noise(rx1,rz);
      float y2 = 200 * noise(rx2*0.2,rz*0.1);
      y2 += 40 * noise(rx2*0.5,rz*0.5);
      y2 += 15 * noise(rx2,rz);

      if (debug)
        stroke(y1);
      else {
        fill(200 * noise(rx1*0.4,rz*0.4),255,128 * noise(rx1*0.1,rz*0.1));
        if (y1<32)
          fill(255);
      }
      vertex((i+dx)*s, y1 , (j+dy)*s); 
      if (debug)
        stroke(y2);
      else {
        fill(200 * noise(rx2*0.4,rz*0.4),255,128 * noise(rx2*0.1,rz*0.1));
        if (y2<32)
          fill(255);
      }    
      vertex((i+dx+1)*s, y2 , (j+dy)*s); 
    }
    endShape();
  }
}

void renderWater(){
  if (!debug)
    fill(0,128,255);

  for (float x = -1; x<1; x+= 0.25){
    beginShape(QUAD_STRIP); 
    for (float y = -1; y<=1; y+= 0.25){
      vertex(g*s*x, 80 , g*s*y); 
      vertex(g*s*(x+0.25), 80 , g*s*y);
    }
    endShape();
  }

}